;*********************************************************************************
;




















;
;				HAM GENERATEUR
;
;		          PROGRAMME POUR GENERATEUR HF DE F6EHJ
;******************************************************************************


;                             VERSION DU 15 DECEMBRE 2000

;                             CALIBRATION FREQUENCE PAR INTRODUCTION

;                             FREQUENCE REELLE HORLOGE : 79 999 210 Hz

;                             VERSION OPERATIONNELLE

;********************************************************************************

;			VERSION DU 14 DECEMBRE 2000

;		          AJOUT PAS 100 kHZ

;                             AJOUT BANDES 36MHz et 500 kHz
                              
;                             AJOUT TIMERS

;                             MODIFICATION ATTENTE SWITCHES

;********************************************************************************

;			VERSION DU 11 DECEMBRE 2000

;		          MODIFICATION POUR CODEUR MPS
;                             
;                             
;***********************************************************************************

;		
;
;RA0	OUT		DATA	AD9850 ET 74HC595's
;RA1	OUT		FQ_UD	AD9850 
;RA2	OUT		CLK	74HC595
;RA3	OUT		W_CLK	AD9850
;RA4	N/U		

;RB0	IN		ENCODEUR OPTIQUE
;RB1	IN		ENCODEUR OPTIQUE
;RB2	OUT		E_LCD
;RB3	OUT		LATCH	74HC595
;RB4	IN		CHANGEMENT DE BANDE
;RB5	IN		CHANGEMENT DE PAS
;RB6	N/U
;RB7	OUT		RS_LCD
			
	



;*********************************************************************************


	LIST	P=16F84;f=inhx8m

	__CONFIG	H'3FF9'

; Xtal 4MHz (16 MHz utilisé)
	
;Définition des Labels


#DEFINE		_DATA		PORTA,0		;data DDS et LCD
#DEFINE		FQ_UD		PORTA,1		;validation DDS
#DEFINE		CLK595		PORTA,2		;clock 74HC595
#DEFINE		W_CLK   	          PORTA,3		;clock DDS

#DEFINE		E		PORTB,2             ;E_LCD
#DEFINE		LATCH595	          PORTB,3		;latch 74HC595
#DEFINE		SWPAS		PORTB,4		;entrée switch pas
#DEFINE		SWBANDE		PORTB,5		;entrée switch bande
#DEFINE		VDD		PORTB,6		;Vdd_LCD
#DEFINE		RS		PORTB,7		;RS_LCD


#DEFINE		CARRY_BIT	STATUS,0		          ;C
#DEFINE		ZERO_BIT	STATUS,2		          ;Z
#DEFINE		BANK0		BCF	STATUS,5	;select page 0
#DEFINE		BANK1		BSF	STATUS,5	;select page 1
#DEFINE		RBPU0		BCF	OPT_REG,7	;configuration E/S RB


		

;Adresses Registres

STATUS	equ	03
PORTA	equ	05
PORTB	equ	06
trisa	equ	85
trisb	equ	86
INTCON	equ	0B
RBIF	equ	0
GIE	equ	7
RBIE	equ	3
OPT_REG	equ	81
PCLATH	equ	0A





;Adresses Variables


ACC0	equ	0C		;registres DDS
ACC1	equ	0D		;registres DDS
ACC2	equ	0E		;registres DDS
ACC3	equ	0F		;registres DDS
ACC4	equ	10		;registres DDS
INCC	equ	11		;Compteur UP/DWN
LSD	equ	12		;Variable pour temporisation
MSD	equ	13		;Variable pour temporisation		
LCD_0	equ	14		;registres LCD
LCD_1	equ	16		;registres LCD
LCD_2	equ	17		;registres LCD
LCD_3	equ	18		;registres LCD
LCD_4	equ	19		;registres LCD
LCD_5	equ	1A		;registres LCD
LCD_6	equ	1B		;registres LCD
PASSEL	equ	1C		;variable PAS
W595_2	equ	1F		;variable chargement DDS/LCD
L595_1	equ	20		;présélecteur
NEW	equ	21		;variable encodeur
OLD	equ	22		;variable encodeur
_W	equ	23		;copie de W
_STATUS	equ	24		;copie de STATUS
LASTPB	equ	25		;Pas Bande
timer2	equ	26		;delay
LOAD0	equ	27		;poids digit LCD
LOAD1	equ	28		;poids digit LCD
LOAD2	equ	29		;poids digit LCD
LOAD3	equ	2A		;poids digit LCD
FI0	equ	2B		;registre offset FI
FI1	equ	2C		;registre offset FI
FI2	equ	2D		;registre offset FI
FI3	equ	2E		;registre offset FI
timer1	equ	2F		;delay
TEMP	equ	30		;variable temporaire
TEMP2	equ	31		;variable temporaire
TEMP5	equ	32		;variable temporaire
COUNT	equ	33		;compteur de bit pour chargement DDS
CNTDWN    equ       34
CNTUP     equ       35




;******************************************************************************			


	ORG	0

	GOTO	INIT

;*****************************************************************************	
;
;		HANDLER D'INTERRUPTION
;
;*****************************************************************************


	ORG	4		;adresse du vecteur d'interruption
	
	MOVWF	_W		;sauvegarde des registres
	SWAPF	STATUS,W
	MOVWF	_STATUS
	GOTO	INTSERV		;que s'est-il passé ?
	
;****************************************************************************
;$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
;
;			PROGRAMME PRINCIPAL
;
;$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
;****************************************************************************
	
;			Défini les ports RA et RB en E/S

INIT	CLRF	PORTA		;RAZ Port A
	CLRF	PORTB

	BANK1			;accès Bank1
	MOVLW	b'00000000'	;RA en sortie
	MOVWF	trisa		;porta en sortie
	
	MOVLW	b'00110011'	;Conf RB 
	MOVWF	trisb
	RBPU0			;pull-up actif
	BANK0
	CLRF	PORTB


          
         
	
;*****************************************************************************

;				INIT DDS 9850 Par RAZ


	CLRF	ACC0
	CLRF	ACC1
	CLRF	ACC2
	CLRF	ACC3
	CLRF	ACC4
	CALL	LD9850
	
    
          CLRF      CNTDWN
          CLRF      CNTUP

;****************************************************************************

	
; 			INTIALISATION DE L'AFFICHEUR LCD
;

               
	CALL	INITLCD
	
	

;;****************************************************************************************

; 			INITIALISATION DU PAS par défaut (10Hz)
	MOVLW	1
	MOVWF	PASSEL
	CALL	PAS10H		;Pas par défaut (10 Hz)
;	
;	
;****************************************************************************************
;	
;			INITIALISATION DE LA BANDE PAR DEFAUT 
;
DOUDOU	MOVLW	4           	;Bande par défaut: 10000.00 kHz
	MOVWF	INCC
	CALL	SCRUTE		;Charge DDS
     	CALL	SCRBAND

;*****************************************************************************************

;			 -TITRE- POINT DECIMAL -CALL
;******************************************************************************************

	MOVLW	b'11000000'
    	CALL	CHRPOS
	MOVLW	'H'
	CALL	DATALCD
	MOVLW	'A'
	CALL	DATALCD
	MOVLW	'M'
	CALL	DATALCD
	MOVLW	' '
	CALL	DATALCD
	MOVLW	'G'
	CALL	DATALCD
	MOVLW	'e'
	CALL	DATALCD
	MOVLW	'n'
	CALL	DATALCD
	MOVLW	'e'
	CALL	DATALCD

	
	MOVLW	b'11001011'
	CALL	CHRPOS
	
	MOVLW	'F'
	CALL	DATALCD
	MOVLW	'6'
	CALL	DATALCD
	MOVLW	'E'
	CALL	DATALCD
	MOVLW	'H'
	CALL	DATALCD
	MOVLW	'J'
	CALL	DATALCD

	MOVLW	b'10000110'	; affiche sur LCD 1ème ligne - position 6
	CALL	CHRPOS
	MOVLW	'.'
	CALL	DATALCD

;*****************************************************************************************	


;			INITIALISATION DU CODEUR OPTIQUE

	
SE	MOVF	PORTB,0		;init codeur optique
	MOVWF	OLD
	MOVLW	b'00000011'	;RB0 et RB1 en entrée codeur
	ANDWF	OLD,1


;***********************************************************************************************
;		BRANCHEMENT AU PROGRAMME DE SCRUTATION ENCODEUR OPTIQUE
;
	GOTO	DEB
;*********************************************************************************************

;			TRAITEMENT DES INTERRUPTIONS

;			SUR DETECTION DES SWITCHES

;		CHANGEMENT DE PAS, CHANGEMENT DE BANDE et BFO


;LE STATUS DU BIT MIS A ZERO (SUITE A PRESSION SWITCH) EST POSITIONNE
;DANS LE PORTB
;IL SUFFIT DE LIRE LE BIT EN QUESTION POUR DETERMINER LEQUEL DES DEUX
;SWITCHES A ETE ACTIVE

;RB4 EST LE CHANGEMENT DE PAS
;RB5 EST LE CHANGEMENT DE BANDE
;RB6 EST LA MISE EN/HORS SERVICE DES FILTRES AUDIO
;RB7 EST LE CHANGEMENT DE BANDE LATERALE (BFO)

;25 Instructions
;***********************************************************************************************


INTSERV
	CALL	wait_16ms
	MOVF	PORTB,0		;save valeur PORTB
	MOVWF	TEMP5		;dans TEMP
	BTFSS	LASTPB,5	          ;bit 5=0 ? (switch pressé)
	CALL	RB5CHG		;si oui traite interruption correspondante
	BTFSS	LASTPB,4	          ;sinon test bit 4
	CALL	RB4CHG		;si bit4=0, traite l'interruption correspondante
	
          GOTO	CLR_INT		;sinon RAZ interrupt
	
RB5CHG	CALL	BANDCHG		;traitement changement de bande
	RETURN

RB4CHG	CALL	PASCHG		;traitement changement de pas		
	RETURN
	
	
CLR_INT	MOVF	TEMP5,0
	MOVWF	LASTPB	
	BCF	INTCON,RBIF	;CLEAR INT FLAG
	BCF	INTCON,GIE	;DISABLE INTERRUPTS

	SWAPF     _STATUS,W
	MOVWF     STATUS
	SWAPF     _W,F
	SWAPF     _W,W
	RETFIE

;****************************************************************************
;****************************************************************************


;		AUTORISATION INTERRUPTION ET BOUCLE ENCODEUR

;LE REGISTRE D'INTERRUPTION (INTCON) EST CONFIGURE POUR LE PORT B
;A SAVOIR RB4 à RB7 PAR LE BIT RBIE
;TOUTE PRESSION SUR LES SWITCHES CHANGEMENT DE BANDE, CHANGEMENT DE PAS
;BFO et FILTRES
;PROVOQUE UNE INTERRUPTION DE LA BOUCLE DE SCRUTATION DE L'ENCODEUR.

;EN CAS D'INTERRUPTION, LE PROGRAMME SE BRANCHE A L'ADRESSE 04 CORRESPONDANT
;AU PROGRAMME HANDLER

;LE PORT B EST CABLE AVEC "PULL UP" ET EST A 1 SANS RESISTANCE, AU +5V
;CECI PERMET DE DISPOSER LES SWITCHES DIRECTEMENT ENTRE LE PORT ET LA MASSE
;UNE RESISTANCE DE 100 OHMS EN SERIE REDUIT LES RISQUES DE COURANT TROP ELEVE


;****************************************************************************


DEB	
	CLRF	INTCON		;RAZ interrupt
	BSF	INTCON,GIE	;autorise global interupt
	BSF	INTCON,RBIE	;autorise PORTB interrupt
	BTFSC	INTCON,RBIF	;Switch activé ?
	GOTO	DEB		;SI OUI interruption et branche INTSERV
				;traite l'interruption et revient à DEB
	GOTO	ENCOD		;SINON scrute encodeur	
	
		
;***************************************************************************
; 		BOUCLE DE SCRUTATION PERMANENTE ENCODEUR OPTIQUE

; L'encodeur optique utilise les ports RB0 et RB1. 
; Deux ports sont nécessaires pour détecter le sens de rotation.

; La scrutation est permanente et c'est la tâche de fond du PIC.
; Cette tâche est suspendue à chaque interruption.
;
;30 Instructions 
;***************************************************************************	
	
	
		
ENCOD	MOVF	PORTB,0		;lecture RB
	MOVWF	NEW		;NEW=RB
	MOVLW	b'00000011'
	ANDWF	NEW,1		;isole RB0 et RB1
	MOVF	NEW,0		;W=NEW
	MOVWF	TEMP		;TEMP=W=NEW
	MOVF	OLD,0		;W=OLD
	BCF	ZERO_BIT
	XORWF	TEMP,1		;XOR NEW et OLD dans TEMP
	BTFSC	ZERO_BIT	          ;si NEW=OLD return
	GOTO	DEB		;retourne scruter 
	
	
	MOVF	OLD,0
	MOVWF	TEMP
	BCF	CARRY_BIT
	RLF	OLD,1		;shift gauche OLD ds OLD
	MOVF	NEW,0		;W=NEW
	BCF	ZERO_BIT	
	XORWF	OLD,1		;XOR OLD shifté et NEW dans OLD-test du sens de rotation
	BTFSC	OLD,1		;TEST BIT1 de old!!!! 
				;Attention ce bit varie en fonction du PORT utilisé
				;pour RB0 et RB1=1
				;pour RB4 et RB5=5
				
	GOTO	DWNF
	
	INCF      CNTUP
          MOVLW     4
    	SUBWF	CNTUP,W
    	BTFSC	ZERO_BIT            ; si<> 4 retourne
          GOTO      UPL       	
          MOVF	NEW,0		;met OLD à jour avec NEW	
	MOVWF	OLD	
	GOTO      DEB
	
	
	
	
UPL	CALL	UPLCD		;si 1 incrémente LCD
	CALL	FQCY		;met à jour fréquence DDS	
	CLRF      CNTUP
	MOVF	NEW,0		;met OLD à jour avec NEW	
	MOVWF	OLD
	GOTO	DEB
	
	
DWNF      INCF      CNTDWN
          MOVLW     4
    	SUBWF	CNTDWN,W
	BTFSC	ZERO_BIT 
	GOTO      DWNL       	
          MOVF	NEW,0		;met OLD à jour avec NEW	
	MOVWF	OLD	
	GOTO      DEB

	
DWNL	CALL	DWNLCD		;si 0 décrémente LCD
	CALL	FQCY		;met à jour fréquence DDS
	CLRF      CNTDWN
          MOVF	NEW,0		;met OLD à jour avec NEW	
	MOVWF	OLD		
	GOTO	DEB
	
	
;FIN DE ROUTINE ENCODEUR OPTIQUE (OUF!)
	


;*********************************************************************************
; 		FIN DE BOUCLE
;*********************************************************************************

			
	
	
;**********************************************************************************
;S/R PASCHG: selectionne un des 4 pas (scrutation circulaire)
;            par action sur le bouton poussoir PAS
;
;24 Instructions
;**********************************************************************************

PASCHG

	INCF	PASSEL,1
	MOVLW	6
	SUBWF	PASSEL,W		
	BTFSS	ZERO_BIT		;=5?
	GOTO	FIRST	           
	CLRF	PASSEL
	GOTO	TERM
	
FIRST	MOVLW	1			;non, <5
	SUBWF	PASSEL,W		;1er pas ? (10Hz)
	BTFSC	ZERO_BIT           
	CALL	PAS10H

	MOVLW	2
	SUBWF	PASSEL,W		;2ème pas ? (100Hz)
	BTFSC	ZERO_BIT           
	CALL	PAS100H

	MOVLW	3
	SUBWF	PASSEL,W		;3ème pas ?(1kHz)
	BTFSC	ZERO_BIT            
	CALL	PAS1K

	MOVLW	4
	SUBWF	PASSEL,W		;4ème pas
	BTFSC	ZERO_BIT
	CALL	PAS10K
	
	MOVLW	5
	SUBWF	PASSEL,W		;5ème pas
	BTFSC	ZERO_BIT
	CALL	PAS100K
	
	
TERM	RETURN
	
;*********************************************************************************

;********************************************************************************
;S/R BANDCHG Changement de bande - Scrutation circulaire
;            par action sur bouton poussoir BANDE

;incrémente compteur-Test si>10 - appel SCRUTE pour ID n° bande

;11 instructions
;********************************************************************************
		
BANDCHG
TOUR	INCF	INCC,1			;incrémente compteur et save ds INCC
	MOVLW	d'12'			;hors domaine (1 to 11)
	SUBWF	INCC,W	
	BTFSS	ZERO_BIT       	 	;10 ?
	GOTO	READYSC			;si<10 scrute
	CLRF	INCC
	GOTO	TOUR
	RETURN
READYSC	CALL	SCRUTE
	CALL	SCRBAND
	RETURN			;si> ou=11 =1


;*********************************************************************************
; SCRUTE: défini le N° de bande (1 à 11)- Prépare le chargement DDS
;
;41 Instructions
;*********************************************************************************
SCRUTE	

	MOVLW	1			;Bande 1.8 ?
	SUBWF	INCC,W
	BTFSC	ZERO_BIT           	 
	CALL	LDB1.8
	
	MOVLW	2			;Bande 3.5 ?
	SUBWF	INCC,W
	BTFSC	ZERO_BIT            	
	CALL	LDB3.5
	
	MOVLW	3			;Bande 7 ?
	SUBWF	INCC,W
	BTFSC	ZERO_BIT            	
	CALL	LDB7
	
	MOVLW	4			;Bande 10 ?
	SUBWF	INCC,W
	BTFSC	ZERO_BIT            	
	CALL	LDB10
	
	MOVLW	5			;Bande 14 ?
	SUBWF	INCC,W
	BTFSC	ZERO_BIT            	
	CALL	LDB14
	
	MOVLW	6			;Bande 18 ?
	SUBWF	INCC,W
	BTFSC	ZERO_BIT            	
	CALL	LDB18
	
	MOVLW	7			;Bande 21 ?
	SUBWF	INCC,W
	BTFSC	ZERO_BIT           
	CALL	LDB21
	
	MOVLW	8			;Bande 24 ?
	SUBWF	INCC,W
	BTFSC	ZERO_BIT           
	CALL	LDB24
	
	MOVLW	9			;Bande 28 ?
	SUBWF	INCC,W
	BTFSC	ZERO_BIT		
	CALL	LDB28
	
	MOVLW	d'10'			;Bande 28 ?
	SUBWF	INCC,W
	BTFSC	ZERO_BIT		
	CALL	LDB36
	
	MOVLW	d'11'			;Bande 28 ?
	SUBWF	INCC,W
	BTFSC	ZERO_BIT		
	CALL	LDB05
	RETURN
	
;***********************************************************************
; Subroutine pour afficher les fréquences de début des bandes OM dans DDS
; et sélection du filtre préselecteur correspondant

;88 Instructions
;***********************************************************************

;Bande 1.8 

LDB1.8	
	MOVLW	'0'
	MOVWF	LCD_5		;mise à jour affichage LCD
	MOVLW	'1'
	MOVWF	LCD_4
	MOVLW	'8'
	MOVWF	LCD_3
	
	RETURN
	
;Bande 3.5 

LDB3.5

	MOVLW	'0'
	MOVWF	LCD_5
	MOVLW	'3'
	MOVWF	LCD_4
	MOVLW	'6'
	MOVWF	LCD_3
	
	RETURN
	
;Bande 7 

LDB7
	MOVLW	'0'	
	MOVWF	LCD_5
	MOVLW	'7'
	MOVWF	LCD_4
	MOVLW	'0'
	MOVWF	LCD_3

	RETURN

	
;Bande 10  F INIT 10 000

LDB10

	MOVLW	'1'
	MOVWF	LCD_5
	MOVLW	'0'
	MOVWF	LCD_4
	MOVLW	'0'
	MOVWF	LCD_3
	MOVLW	'0'
	MOVWF	LCD_2
	MOVLW	'0'
	MOVWF	LCD_1
	MOVLW	'0'
	MOVWF	LCD_0
	MOVLW	'0'
	MOVWF	LCD_6

	RETURN

	
;Bande 14 

LDB14	
	MOVLW	'1'
	MOVWF	LCD_5
	MOVLW	'4'
	MOVWF	LCD_4
	MOVLW	'0'
	MOVWF	LCD_3

	RETURN

	
;Bande 18 (LO=23.713MHz)

LDB18	
	MOVLW	'1'
	MOVWF	LCD_5
	MOVLW	'8'
	MOVWF	LCD_4
	MOVLW	'0'
	MOVWF	LCD_3	
	
	RETURN

	
;Bande 21 (LO=26645 MHz)

LDB21	

	MOVLW	'2'
	MOVWF	LCD_5
	MOVLW	'1'
	MOVWF	LCD_4
	MOVLW	'0'
	MOVWF	LCD_3
	
	RETURN
	
;Bande 24 (LO=30 535 MHz)  24890

LDB24	
	
	MOVLW	'2'
	MOVWF	LCD_5
	MOVLW	'4'
	MOVWF	LCD_4
	MOVLW	'8'
	MOVWF	LCD_3	
		
	RETURN

	
;Bande 28.5 

LDB28	

	MOVLW	'2'
	MOVWF	LCD_5
	MOVLW	'8'
	MOVWF	LCD_4
	MOVLW	'5'
	MOVWF	LCD_3

	RETURN
	
LDB36	

	MOVLW	'3'
	MOVWF	LCD_5
	MOVLW	'6'
	MOVWF	LCD_4
	MOVLW	'0'
	MOVWF	LCD_3

	RETURN



	RETURN
	
LDB05

	MOVLW	'0'
	MOVWF	LCD_5
	MOVLW	'0'
	MOVWF	LCD_4
	MOVLW	'5'
	MOVWF	LCD_3
	MOVLW	'0'
	MOVWF	LCD_2
	MOVLW	'0'
	MOVWF	LCD_1

	RETURN	

;*************************************************************************
;S/R   PAS: CHARGE LE PAS EN FONCTION DE LA SELECTION
;
;73 Instructions
;*************************************************************************

PAS10H	
	MOVLW	b'10001010'	;adresse DDRAM (1ère ligne dans ce cas)
	MOVWF	W595_2
	CALL	CMDLCD

          BSF       RS
	
	MOVLW	' '		;.
	CALL	DATALCD
	MOVLW	' '		;.
	CALL	DATALCD
	MOVLW	'1'		;.
	CALL	DATALCD
	MOVLW	'0'		;.
	CALL	DATALCD
	MOVLW	'H'		;.
	CALL	DATALCD
	MOVLW	'z'		;.
	CALL	DATALCD
	
	RETURN
	
PAS100H	
	MOVLW	b'10001011'	;adresse DDRAM (1ère ligne dans ce cas)
	MOVWF	W595_2
	CALL	CMDLCD

          BSF       RS
          
          MOVLW	'1'		;.
	CALL	DATALCD
	MOVLW	'0'		;.
	CALL	DATALCD
	MOVLW	'0'		;.
	CALL	DATALCD


	RETURN

PAS1K		
	MOVLW	b'10001011'	;adresse DDRAM (1ère ligne dans ce cas)
	MOVWF	W595_2
	CALL	CMDLCD


          BSF       RS
          
	MOVLW	' '		;.
	CALL	DATALCD
	MOVLW	'1'		;.
	CALL	DATALCD
	MOVLW	'k'		;.
	CALL	DATALCD
	MOVLW	'H'		;.
	CALL	DATALCD
	MOVLW	'z'		;.
	CALL	DATALCD
	
	RETURN

PAS10K		
	MOVLW	b'10001011'	;adresse DDRAM (1ère ligne dans ce cas)
	MOVWF	W595_2
	CALL	CMDLCD


          BSF       RS
          
	MOVLW	'1'		;.
	CALL	DATALCD
	MOVLW	'0'		;.
	CALL	DATALCD

	RETURN
	
PAS100K		
	MOVLW	b'10001010'	;adresse DDRAM (1ère ligne dans ce cas)
	MOVWF	W595_2
	CALL	CMDLCD

          BSF       RS
          
	MOVLW	'1'		;.
	CALL	DATALCD
	MOVLW	'0'		;.
	CALL	DATALCD	

	RETURN



;********************************************************************************
; S/R UPLCD :Incrémente LCD

; Incrémentation fréquence: 10 Hz 
; La valeur de l'incrémentation a un entier décimal arrondi à la valeur hexadecimale corr.
;
;76 Instructions
;********************************************************************************

UPLCD	MOVLW	1
	SUBWF	PASSEL,0	;pas=1 (10Hz)
	BTFSC	ZERO_BIT
	GOTO	LCD10H		

	MOVLW	2		;pas=100Hz?
	SUBWF	PASSEL,0
	BTFSC	ZERO_BIT
	GOTO	LCD100H		;si oui va incrémenter de 100Hz
	
          MOVLW	3		;sinon pas=1KHz ?
	SUBWF	PASSEL,0
	BTFSC	ZERO_BIT
	GOTO	LCD1K		;si oui va incrémenter de 1kHz
	

	MOVLW	4		;sinon pas=10KHz ?
	SUBWF	PASSEL,0
	BTFSC	ZERO_BIT
	GOTO	LCD10K		;si oui va incrémenter de 10kHz
	GOTO	LCD100K		;sinon de 100kHz


LCD10H	MOVLW	'9'
	XORWF	LCD_6,0
	BTFSS	ZERO_BIT
	GOTO	INC10H
	MOVLW	'0'
	MOVWF	LCD_6
	CALL	DISP10H
	
LCD100H	MOVLW	'9'
	XORWF	LCD_0,0
	BTFSS	ZERO_BIT
	GOTO	INC100H
	MOVLW	'0'
	MOVWF	LCD_0
	CALL	DISP100H
	
		
LCD1K	MOVLW	H'39'
	XORWF	LCD_1,0
	BTFSS	ZERO_BIT
	GOTO	INC1K
	MOVLW	H'30'
	MOVWF	LCD_1
	CALL	DISP1K
	
	
LCD10K	MOVLW	H'39'
	XORWF	LCD_2,0
	BTFSS	ZERO_BIT
	GOTO	INC10K
	MOVLW	H'30'
	MOVWF	LCD_2
	CALL	DISP10K
	
	
LCD100K	MOVLW	H'39'
	XORWF	LCD_3,0
	BTFSS	ZERO_BIT
	GOTO	INC100K
	MOVLW	H'30'
	MOVWF	LCD_3
	CALL	DISP100K
	
	
	MOVLW	H'39'
	XORWF	LCD_4,0
	BTFSS	ZERO_BIT
	GOTO	INC1M
	MOVLW	H'30'
	MOVWF	LCD_4
	CALL	DISP1M
	GOTO	INC10M
	
INC10H	INCF	LCD_6,1
	CALL	DISP10H
	RETURN
	
INC100H	INCF	LCD_0,1
	CALL	DISP100H
	RETURN
	
INC1K	INCF	LCD_1,1
	CALL	DISP1K
	RETURN
	
INC10K	INCF	LCD_2,1
	CALL	DISP10K
	RETURN
	
INC100K	INCF	LCD_3,1
	CALL	DISP100K
	RETURN
	
INC1M	INCF	LCD_4,1
	CALL	DISP1M
	RETURN
	
INC10M	INCF	LCD_5,1
	CALL	DISP10M
	RETURN


;********************************************************************************
; S/R DWNLCD :Décrémente LCD
;
;
;DWNLCD détermine le pas courant (PASSEL) et en déduit la valeur de décrémentation
;à charger pour l'afficheur
;
;76 Instructions
;********************************************************************************
	
DWNLCD	MOVLW	1
	SUBWF	PASSEL,0	;pas=1 (10Hz)
	BTFSC	ZERO_BIT
	GOTO	LCDH10
	
	MOVLW	2		;pas=100Hz?
	SUBWF	PASSEL,0
	BTFSC	ZERO_BIT
	GOTO	LCDH100		;si oui va décrémenter de 100Hz
	
	
	MOVLW	3		;pas=100Hz?
	SUBWF	PASSEL,0
	BTFSC	ZERO_BIT
	GOTO	LCDK1		;si oui va décrémenter de 100Hz	
	
	MOVLW	4		;sinon pas=1KHz ?
	SUBWF	PASSEL,0
	BTFSC	ZERO_BIT
	GOTO	LCDK10		;si oui va décrémenter de 1kHz
	GOTO	LCDK100		;sinon de 10kHz
	
LCDH10	MOVLW	H'30'
	SUBWF	LCD_6,0	
	BTFSS	ZERO_BIT
	GOTO	DEC_6
	MOVLW	H'39'
	MOVWF	LCD_6
	CALL	DISP10H
	
LCDH100	MOVLW	H'30'
	SUBWF	LCD_0,0	
	BTFSS	ZERO_BIT
	GOTO	DEC_0
	MOVLW	H'39'
	MOVWF	LCD_0
	CALL	DISP100H
	
LCDK1	MOVLW	H'30'
	SUBWF	LCD_1,0
	BTFSS	ZERO_BIT
	GOTO	DEC_1
	MOVLW	H'39'
	MOVWF	LCD_1
	CALL	DISP1K

LCDK10	MOVLW	H'30'
	SUBWF	LCD_2,0
	BTFSS	ZERO_BIT
	GOTO	DEC_2
	MOVLW	H'39'
	MOVWF	LCD_2
	CALL	DISP10K
	
LCDK100	MOVLW	H'30'
	SUBWF	LCD_3,0
	BTFSS	ZERO_BIT
	GOTO	DEC_3
	MOVLW	H'39'
	MOVWF	LCD_3
	CALL	DISP100K
	
	MOVLW	H'30'
	SUBWF	LCD_4,0
	BTFSS	ZERO_BIT
	GOTO	DEC_4
	MOVLW	H'39'
	MOVWF	LCD_4
	CALL	DISP1M
	
	DECF	LCD_5,1
	CALL	DISP10M
	RETURN

DEC_6	DECF	LCD_6,1
	CALL	DISP10H
	RETURN	
	
DEC_0	DECF	LCD_0,1
	CALL	DISP100H
	RETURN
	
DEC_1	DECF	LCD_1,1
	CALL	DISP1K
	RETURN
	
DEC_2	DECF	LCD_2,1
	CALL	DISP10K
	RETURN
	
DEC_3	DECF	LCD_3,1
	CALL	DISP100K
	RETURN
	
DEC_4	DECF	LCD_4,1
	CALL	DISP1M
	RETURN
	
	

;***************************************************************************************************
;
;S/R INITLCD: CONFIGURE L'AFFICHEUR EN 2 LIGNES DE 16 CARACTERES ET DEFINIT LES OPTIONS
;
;25 Instructions
;*************************************************************************************************


INITLCD        
	
	
	CALL	ATTENTE		;attente pourinitialisation LCD
	
	MOVLW	b'00111000'	;INIT_1
	MOVWF	W595_2
	CALL	CMDLCD
	CALL	ATTENTE


	MOVLW	b'00111000'	;INIT_2
	MOVWF	W595_2
	CALL	CMDLCD
	CALL	ATTENTE


	MOVLW	b'00111000'	;INIT_3
 	MOVWF	W595_2
	CALL	CMDLCD
	CALL	ATTENTE


	MOVLW	b'00111100'         ;function SET
	MOVWF	W595_2
	CALL	CMDLCD
	CALL	ATTENTE
	

          MOVLW	b'00001100'	;ON/OFF control
	MOVWF	W595_2
	CALL	CMDLCD
	CALL	ATTENTE

	
	MOVLW	b'00000001'	;Clear Display
	MOVWF	W595_2
	CALL	CMDLCD
	CALL	ATTENTE
	
          MOVLW	b'00000110'	;Entry Mode SET
	MOVWF	W595_2
	CALL	CMDLCD
	
	RETURN
;********************************************************************************************
;
;S/R CMDLCD: ENVOI D'UNE COMMANDE A L'AFFICHEUR LCD
;
;10 Instructions
;********************************************************************************************
	
CMDLCD

          BCF       RS      
         
          MOVF	W595_2,0	
          CALL	LD595
	
          BSF       E
          BCF       E
          
	RETURN
	
;***********************************************************************************************
;
;S/R DISP100H, 1K, 10K, 100K, 1M, 10M

;CES ROUTINES METTENT A JOUR LE SEUL DIGIT DE L'AFFICHEUR QUI A CHANGE

;CECI PERMET D'OPTIMISER LES TEMPS DE CALCUL DONT CES ROUTINES SONT TRES CONSOMMATRICES
;
;56 Instructions
;*********************************************************************************************
;
DISP10H
	
	MOVLW	b'10001000'		;adresse DDRAM (1ère ligne dans ce cas)
	MOVWF	W595_2
	CALL	CMDLCD

          BSF       RS

	MOVF	LCD_6,0			;contenu des 6 mots "fréquence"
	CALL	DATALCD	
	RETURN
	
DISP100H
	
	MOVLW	b'10000111'
	MOVWF	W595_2
	CALL	CMDLCD
	
          BSF       RS
          
	MOVF	LCD_0,0			;contenu des 6 mots "fréquence"
	CALL	DATALCD
	RETURN

DISP1K
	
	MOVLW	b'10000101'		;adresse DDRAM (1ère ligne dans ce cas)
	MOVWF	W595_2
	CALL	CMDLCD

	BSF       RS
	
	MOVF	LCD_1,0			;contenu des 6 mots "fréquence"
	CALL	DATALCD
	RETURN
	
DISP10K
	
	MOVLW	b'10000100'		;adresse DDRAM (1ère ligne dans ce cas)
	MOVWF	W595_2
	CALL	CMDLCD
	
          BSF       RS
          
	MOVF	LCD_2,0			;contenu des 6 mots "fréquence"
	CALL	DATALCD
	RETURN

DISP100K
	
	MOVLW	b'10000011'		;adresse DDRAM (1ère ligne dans ce cas)
	MOVWF	W595_2
	CALL	CMDLCD

          BSF       RS
	
	
	MOVF	LCD_3,0			;contenu des 6 mots "fréquence"
	CALL	DATALCD
	RETURN
	
DISP1M
	
	MOVLW	b'10000010'		;adresse DDRAM (1ère ligne dans ce cas)
	MOVWF	W595_2
	CALL	CMDLCD
	
          BSF       RS
          
	MOVF	LCD_4,0			;contenu des 6 mots "fréquence"
	CALL	DATALCD
	RETURN

DISP10M
	
	MOVLW	b'10000001'		;adresse DDRAM (1ère ligne dans ce cas)
	MOVWF	W595_2
	CALL	CMDLCD

          BSF       RS
          
	MOVF	LCD_5,0			;contenu des 6 mots "fréquence"
	CALL	DATALCD
	RETURN

	
;****************************************************************************************************	
;
;S/R DATALCD: TRANSMET UN CARACTERE POUR AFFICHAGE SUR LCD ET AFFICHE
;
;****************************************************************************************************


	
DATALCD

	BSF	RS
	BSF	E
	MOVWF	W595_2
	CALL	LD595
	BCF	E

	RETURN
	
;*********************************************************************************************

;*****************************************************************************************
;S/R LD9850:  TRANSMISSION DU MESSAGE "Fréquence" à un AD9850
;	      PAR CHARGEMENT SEQUENTIEL DES 5 OCTETS DANS TEMP
;	      PUIS TRANSMISSION PAR LDBYTE
;*****************************************************************************************

;3 sorties sont nécessaires pour la commande:
;W_CLK:     Serial clock 			(pin 7 ) 
;_DATA:     sortie série vers l'entrée DATA     (pin 25)
;FQ_UD:	prise en compte du mot 			(pin 8 )


;5 registres contiennent le mot de 40 bits à destination du 9850
; ACC0, ACC1, ACC2, ACC3, ACC4

;La transmission des 5bytes au 9850 se fait suivant la séquence
;suivante:

;1. Transfert du byte 0 dans la variable TEMP
;2. Appel à la subroutine LDBYTE pour la sérialisation du 1er byte
;3. Transfert du byte 1 dans la variable TEMP
;4. LDBYTE
;5. ......
;6. Transfert du byte 4 dans la variable TEMP
;7; LDBYTE
;8 SET FQ_UD pour prise en compte du mot de 40 bits
;9 RESET FQ_UD
;10 Fin de chargement

;***********************************************************************	

LD9850	
	MOVF	ACC0,W			;charge séquentiellement la valeur
	MOVWF	TEMP
	CALL	LDBYTE
	
	MOVF	ACC1,W			;de chaque octet du DDS
	MOVWF	TEMP
	CALL	LDBYTE
	
	MOVF	ACC2,W			;dans la variable TEMP
	MOVWF	TEMP
	CALL	LDBYTE
	
	MOVF	ACC3,W			;utilisée par la S/R LDBYTE
	MOVWF	TEMP
	CALL	LDBYTE
	
	MOVF	ACC4,W
	MOVWF	TEMP
	CALL	LDBYTE

  	BSF	FQ_UD			;set latch pulse
	BCF	FQ_UD			;reset latch pulse

	RETURN
;*********************************************************************


;*********************************************************************
; S/R LDBYTE:	 Sérialisation d'un octet
;*********************************************************************

;1. initialisation du compteur de bit à 8 (byte)
;2. RAZ du bit W_CLK
;3. RAZ de l'entrée _DATA
;4. Mise dans la carry du bit de droite
;5. Transmission de la donnée (1 ou 0)
;6. SET bit W_CLK
;7. RAZ bit W_CLK
;8. bit suivant (jusqu'au dernier)
;9. SET FQ_UD
;10. RAZ FQ_UD
;********************************************************************


LDBYTE
	MOVLW	8		;compteur de bits
	MOVWF	COUNT		;on va charger un octet
	BCF	W_CLK		;clear la clock      
BIT       BCF	_DATA		;clear data (entrée A)
          RRF	TEMP,1		;décale vers la droite et met dans la carry
	BTFSC	CARRY_BIT	;test carry. Si 1 met le data à 1 sinon rien (data=0)
	BSF	_DATA
	BSF	W_CLK		;set clock
	BCF     W_CLK	;reset clock
	DECFSZ	COUNT,1		;décremente le compteur pour le bit suivant
	GOTO	BIT		;retourne charger le bit suivant
	RETURN			;retour à SNDSER pour le latch quand les 8 bits ont été chargés
;*********************************************************************************

;*********************************************************************************
;S/R LD595:  TRANSMISSION DU MESSAGE "SORTIE" au 595
;	          PAR CHARGEMENT DES 1 OCTET  
;	    	TRANSMISSION PAR BYT595
;*********************************************************************************


;3 sorties sont nécessaires pour la commande:
;CLK595:	Serial clock 		(pin 11) 
;_DATA5: 	sortie série vers l'entrée DATA     (pin 14)
;LATCH595:	Prise en compte du mot 		(pin 12)

;LA LIGNE DATA EST COMMUNE AU 9850 ET AU 595.


;1. Transfert de l'octet dans la variable TEMP
;2. Appel à la subroutine LDBYTE pour la sérialisation de l'octet
;3. SET LATCH595 pour prise en compte du mot de 8 bits
;4. RESET LATCH595
;5. Fin de chargement


;**********************************************************************************
 
; W595_2 est  affecté à l'afficheur LCD.

;*********************************************************************************	

LD595	

	
	MOVF	W595_2,0   	;contenu du 595_2
	MOVWF	TEMP		;transfert dans TEMP avant appel chargement
	CALL	BYT595
	
 	BSF	LATCH595	          ;set latch pulse
	BCF	LATCH595	          ;reset latch pulse
	RETURN

BYT595	MOVLW	8		;compteur de bits
	MOVWF	COUNT		;on va charger un octet
	BCF	CLK595		;clear la clock      
BIT595    BCF	_DATA		;clear data (entrée A)
          RRF	TEMP,1		;décale vers la droite et met dans la carry
	BTFSC	CARRY_BIT	          ;test carry. Si 1 met le data à 1 sinon rien (data=0)
	BSF	_DATA		;DATA=1
	BSF	CLK595      	;set clock
	BCF	CLK595		;reset clock
	DECFSZ	COUNT,1		;décrémente le compteur pour le bit suivant
	GOTO	BIT595		;retourne charger le bit suivant

 	RETURN		

;**********************************************************************************
;S/R ATTENTE: INTRODUIT UNE TEMPO AVANT PRISE EN COMPTE INFO SWITCH
;**********************************************************************************

ATTENTE                             
	MOVLW     D'255'               
DEL	MOVWF     MSD
	MOVLW     D'255'
	MOVWF     LSD
LOOP3
	DECFSZ    LSD,F
	GOTO      LOOP3
	DECFSZ    MSD,F
	GOTO      LOOP3
	RETURN
	

;**************************************************************************************
;S/R CHRPOS:	Permet de se positionner dans la ligne LCD
;

CHRPOS	MOVWF	W595_2			; S/R permet de se positionner ds la ligne
	CALL	CMDLCD

          BSF       RS
          
	RETURN
	
;**************************************************************************************
;
;					S/R FQCY
;
;**************************************************************************************

;Ce module transforme la valeur affichée par le LCD (7 digits) en 4 octets destinés
;au chargement du DDS.
;
;Chaque digit BCD du LCD est traité individuellement et représente un incrément
;de fréquence dont les valeurs sont issues de la formule:
;
;	F= f Xtal * N /2exp 32
;
; F prend les valeurs de chaque digit: 10Hz, 100Hz, 1kHz, 10kHz, 100kHz, 1MHz et 10MHz.
;
; F Xtal=125,001 540 MHZ dans cette réalisation.
;
; On en déduit N (en hexa) pour chaque valeur de F
;
; 10Hz		01 58
; 100Hz		0D 6C
; 1kHZ		86 37
; 10Khz		05 3E 29
; 100kHz  	34 6D 9C
; 1MHz		02 0C 48 13
; 10MHz		14 7A D0 BF
;
; Chacune de ces constantes est multipliée par le poids du digit correspondant.
; En réalité, chaque valeur est additionnée n fois par le poids du digit.
;
; Puis l'ensemble des résultats est additionné pour former le mot "fréquence"
;
; Exemple: F Affiché= 28534.26 kHz
;
; N= (6*01 58)+(2*0D 6C)+4(86 37)+(3*05 3E 29)+(5*34 6D 9C)+(8*02 0C 48 13)+(2*14 7A D0 BF)
;
;
;Par contre, le chargement de ce résultat dans le DDS, fournirait une fréquence de sortie
;égale à celle affichée.
;Ceci convient parfaitement à un récepteur à conversion directe, par contre, dans le
;cas d'utilisation d'un ou plusieurs changement de fréquence, il est nécessaire d'ajouter
;(ou retrancher) les valeurs des FI.
;Cette opération est réalisée dans le module ADDBFO qui prend en compte les offsets
;du module BFO.
;
;**************************************************************************************************


FQCY	CLRF	TEMP2
	CLRF	ACC0
	CLRF	ACC1
	CLRF	ACC2
	CLRF	ACC3
	CLRF	ACC4
	
XADD10H	
	
	MOVLW	H'19'
	MOVWF	LOAD0
	MOVLW	H'02'
	MOVWF	LOAD1
	CLRF	LOAD2
	CLRF	LOAD3
	
	MOVLW	H'30'
	SUBWF	LCD_6,0		; Soustrait 30 de LCD_6
	BTFSC	ZERO_BIT	; SI R=0 on passe au digit suivant car n*0=0...
	GOTO	XADD100H
	MOVWF	TEMP2		; Multiplicateur
	
	CALL	AGAIN		; sinon on additionne TEMP2 fois
	
XADD100H	
	MOVLW	H'F9'
	MOVWF	LOAD0
	MOVLW	H'14'
	MOVWF	LOAD1
	CLRF	LOAD2
	CLRF	LOAD3
	
	MOVLW	H'30'
	SUBWF	LCD_0,0		; Soustrait 30 de LCD_0
	BTFSC	ZERO_BIT
	GOTO	XADD1K
	MOVWF	TEMP2		; Multiplicateur
	
	CALL	AGAIN
		
XADD1K	
	MOVLW	H'B7'
	MOVWF	LOAD0
	MOVLW	H'D1'
	MOVWF	LOAD1
	CLRF	LOAD2
	CLRF	LOAD3
	
	MOVLW	H'30'
	SUBWF	LCD_1,0		; Soustrait 30 de LCD_1
	BTFSC	ZERO_BIT
	GOTO	XADD10K
	MOVWF	TEMP2		; Multiplicateur
	
	CALL	AGAIN
	
XADD10K	
	
	MOVLW	H'2C'
	MOVWF	LOAD0
	MOVLW	H'31'
	MOVWF	LOAD1
	MOVLW	H'08'
	MOVWF	LOAD2
	CLRF	LOAD3
	
	MOVLW	H'30'
	SUBWF	LCD_2,0		; Soustrait 30 de LCD_2
	BTFSC	ZERO_BIT
	GOTO	XADD100K
	MOVWF	TEMP2		; Multiplicateur
	
	CALL	AGAIN
	
	
XADD100K	
	
	MOVLW	H'BA'
	MOVWF	LOAD0
	MOVLW	H'EB'
	MOVWF	LOAD1
	MOVLW	H'51'
	MOVWF	LOAD2	
	CLRF	LOAD3
	
	MOVLW	H'30'
	SUBWF	LCD_3,0		; Soustrait 30 de LCD_3
	BTFSC	ZERO_BIT
	GOTO	XADD1M
	MOVWF	TEMP2		; Multiplicateur
	
	CALL	AGAIN
		
XADD1M	
	
	MOVLW	H'45'
	MOVWF	LOAD0
	MOVLW	H'35'
	MOVWF	LOAD1
	MOVLW	H'33'
	MOVWF	LOAD2
	MOVLW	H'03'
	MOVWF	LOAD3
	
	MOVLW	H'30'
	SUBWF	LCD_4,0		; Soustrait 30 de LCD_4
	BTFSC	ZERO_BIT
	GOTO	XADD10M
	MOVWF	TEMP2		; Multiplicateur
	
	CALL	AGAIN
		
XADD10M	
	MOVLW	H'B6'		;attention: ce digit peut être "blanc"
	MOVWF	LOAD0		; dans ce cas la valeur = H20
	MOVLW	H'14'
	MOVWF	LOAD1
	MOVLW	H'00'
	MOVWF	LOAD2
	MOVLW	H'20'
	MOVWF	LOAD3

	MOVLW	H'30'
	SUBWF	LCD_5,0		; Soustrait 30 de LCD_0
	BTFSS	CARRY_BIT
	GOTO	LD
	BTFSC	ZERO_BIT
	GOTO	LD
	MOVWF	TEMP2		; Multiplicateur	
		
	CALL	AGAIN
	
LD	CALL	LD9850
	RETURN


AGAIN	CALL	XADD
	DECFSZ	TEMP2,1
	GOTO	AGAIN
	RETURN
	


 ;***************************************************************************
;		S/R XADD: INCREMENTE LE MOT DDS DU PAS EN COURS
;
;
;LOAD0 à LOAD4 contiennent la valeur issue de l'affichage LCD
;Les deux valeurs sont additionnées et rangées dans ACC0 à ACC4
;
;15 Instructions
;****************************************************************************

XADD	MOVF	LOAD0,W
	ADDWF	ACC0,F
	
	MOVF	LOAD1,W
	BTFSC	CARRY_BIT
	INCFSZ	LOAD1,W
	ADDWF	ACC1,F
	
	MOVF	LOAD2,W
	BTFSC	CARRY_BIT		
	INCFSZ	LOAD2,W
	ADDWF	ACC2,F
	
	MOVF	LOAD3,W
	BTFSC	CARRY_BIT
	INCFSZ	LOAD3,W
	ADDWF	ACC3,F
			
	RETURN

;********************************************************************************

;	S/R SCDBAND: INITIALISE LA FREQUENCE A LA MISE SOUS TENSION 
	
SCRBAND	CALL	DISP10H		
	CALL	DISP100H
	CALL	DISP1K		
	CALL	DISP10K
	CALL	DISP100K
	CALL	DISP1M
	CALL	DISP10M
	CALL	FQCY

	RETURN

;**************************************************************************
;
; *****************************************************************************
; *                                                                           *
; * Purpose:  Wait for a specified number of milliseconds.                    *
; *                                                                           *
; *           Entry point wait_128ms:  Wait for 128 msec                      *
; *           Entry point wait_64ms :  Wait for 64 msec                       *
; *           Entry point wait_32ms :  Wait for 32 msec                       *
; *           Entry point wait_16ms :  Wait for 16 msec                       *
; *           Entry point wait_8ms  :  Wait for 8 msec                        *
; *                                                                           *
; *   Input:  None                                                            *
; *                                                                           *
; *  Output:  None                                                            *
; *                                                                           *
; *****************************************************************************
;
wait_128ms  ; ****** Entry point ******    
        movlw   0xFF              ; Set up outer loop 
        movwf   timer1            ;   counter to 255
        goto    outer_loop        ; Go to wait loops
wait_64ms  ; ****** Entry point ******     
        movlw   0x80              ; Set up outer loop
        movwf   timer1            ;   counter to 128
        goto    outer_loop        ; Go to wait loops
wait_32ms   ; ****** Entry point ******    
        movlw   0x40              ; Set up outer loop
        movwf   timer1            ;   counter to 64
        goto    outer_loop        ; Go to wait loops
wait_16ms   ; ****** Entry point ******    
        movlw   0x20              ; Set up outer loop
        movwf   timer1            ;   counter to 32  
        goto    outer_loop        ; Go to wait loops
wait_8ms   ; ****** Entry point ******     
        movlw   0x10              ; Set up outer loop
        movwf   timer1            ;   counter to 16
                                  ; Fall through into wait loops
;
; Wait loops used by other wait routines
;  - 1 microsecond per instruction (with a 4 MHz microprocessor crystal)
;  - 510 instructions per inner loop
;  - (Timer1 * 514) instructions (.514 msec) per outer loop
;  - Round off to .5 ms per outer loop
;
outer_loop                        
        movlw   0xFF              ; Set up inner loop counter
        movwf   timer2            ;   to 255
inner_loop
        decfsz  timer2,f          ; Decrement inner loop counter
        goto    inner_loop        ; If inner loop counter not down to zero, 
                                  ;   then go back to inner loop again
        decfsz  timer1,f          ; Yes, Decrement outer loop counter
        goto    outer_loop        ; If outer loop counter not down to zero,
                                  ;   then go back to outer loop again
        return                    ; Yes, return to caller
;       
; *****************************************************************************
;
 
	END
